Classes:Revenant

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Revenant
Actor type	Monster	Game	(Doom2)
DoomEd Number	66	Class Name	Revenant
Spawn ID	20	Identifier	T_REVENANT

Classes: Revenant
 →StealthRevenant

The Revenant, a bag of bones with armour and, according to some, pants, will send heatseeking missiles into its targets from a distance and punch them when up close.

DECORATE definition

actor Revenant 66
{
  spawnid 20
  obituary "%o couldn't evade a revenant's fireball."
  hitobituary "%o was punched by a revenant."
  health 300
  radius 20
  height 56
  mass 500
  speed 10
  painchance 100
  seesound "skeleton/sight"
  painsound "skeleton/pain"
  deathsound "skeleton/death"
  activesound "skeleton/active"
  MONSTER
  +FLOORCLIP
  +LONGMELEERANGE
  +MISSILEMORE
  states
  {
  Spawn:
    SKEL AB 10 A_Look
    loop
  See:
    SKEL AABBCCDDEEFF 2 A_Chase
    loop
  Melee:
    SKEL G 0 A_FaceTarget
    SKEL G 6 A_SkelWhoosh
    SKEL H 6 A_FaceTarget
    SKEL I 6 A_SkelFist
    goto See
  Missile:
    SKEL J 0 bright A_FaceTarget
    SKEL J 10 bright A_FaceTarget
    SKEL K 10 A_SkelMissile         // See RevenantTracer
    SKEL K 10 A_FaceTarget
    goto See
  Pain:
    SKEL L 5
    SKEL L 5 A_Pain
    goto See
  Death:
    SKEL LM 7
    SKEL N 7 A_Scream
    SKEL O 7 A_NoBlocking
    SKEL P 7
    SKEL Q -1
    stop
  Raise:
    SKEL QPONML 5
    goto See
  }
}