Classes:LostSoul

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Lost Soul
Actor type	Monster	Game	(Doom)
DoomEd Number	3006	Class Name	LostSoul
Spawn ID	110	Identifier	T_LOSTSOUL

Classes: Actor → LostSoul
 →BetaSkull
 →DeadLostSoul

Lost souls have nearly twice as much health as an imp, but they don't shoot fireballs. They fly around and then charge at you for a big bite. These can really be a pain if there are lots of them flying around. In Doom 2, they are spat out by pain elementals as a form of offense.

DECORATE definition

ACTOR LostSoul 3006
{
  Game Doom
  SpawnID 110
  Health 100
  Radius 16
  Height 56
  Mass 50
  Speed 8
  Damage 3
  PainChance 256
  Monster
  +FLOAT
  +NOGRAVITY
  +MISSILEMORE
  +DONTFALL
  +NOICEDEATH
  AttackSound "skull/melee"
  PainSound "skull/pain"
  DeathSound "skull/death"
  ActiveSound "skull/active"
  RenderStyle SoulTrans
  Obituary "$OB_SKULL" // "%o was spooked by a lost soul."
  States
  {
  Spawn:
    SKUL AB 10 Bright A_Look
    Loop
  See:
    SKUL AB 6 Bright A_Chase
    Loop
  Missile:
    SKUL C 10 Bright A_FaceTarget
    SKUL D 4 Bright A_SkullAttack
    SKUL CD 4 Bright
    Goto Missile+2
  Pain:
    SKUL E 3 Bright
    SKUL E 3 Bright A_Pain
    Goto See
  Death:
    SKUL F 6 Bright
    SKUL G 6 Bright A_Scream
    SKUL H 6 Bright
    SKUL I 6 Bright A_NoBlocking
    SKUL J 6
    SKUL K 6
    Stop
  }
}