Classes:Chaingun

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Chaingun
Actor type	Weapon	Game
DoomEd Number	2002	Class Name	Chaingun
Spawn ID	28	Identifier	T_CHAINGUN

Classes: Inventory→Weapon→DoomWeapon→Chaingun

The chaingun is a rapid fire bullet weapon. It is dropped by chaingunners and uses clips for ammo.

DECORATE definition

actor Chaingun : DoomWeapon 2002
{
   Game Doom
   SpawnID 28
   Weapon.SelectionOrder 700
   Weapon.AmmoUse 1
   Weapon.AmmoGive 20
   Weapon.AmmoType "Clip"
   Inventory.PickupMessage "$GOTCHAINGUN" // "You got the chaingun"
   Obituary "$OB_MPCHAINGUN" // "%o was mowed down by %k's chaingun."
   States
   {
   Ready:
     CHGG A 1 A_WeaponReady
     Loop
   Deselect:
     CHGG A 1 A_Lower
     Loop
   Select:
     CHGG A 1 A_Raise
     Loop
   Fire:
     CHGG AB 4 A_FireCGun
     CHGG B 0 A_ReFire
     Goto Ready
   Flash:
     CHGF A 5 Bright A_Light1
     Goto LightDone
     CHGF B 5 Bright A_Light1
     Goto LightDone
   Spawn:
     MGUN A -1
     Stop
   }
}

This is the version of the actor as defined in the previous ZDoom release (2.1.7):

actor Chaingun : Weapon 2002
{
  spawnid 28
  obituary "%o was mowed down by %k's chaingun."
  radius 20
  height 16
  attacksound "weapons/chngun"
  inventory.pickupmessage "You got the chaingun!"
  weapon.selectionorder 700
  weapon.kickback 100
  weapon.ammotype "Clip"
  weapon.ammouse 1
  weapon.ammogive 20
  states
  {
  Ready:
    CHGG A 1 A_WeaponReady
    loop
  Deselect: 
    CHGG A 1 A_Lower
    loop
  Select:
    CHGG A 1 A_Raise
    loop
  Fire:
    CHGG A 0 A_FireBullets (5.6, 0, 1, 5, "BulletPuff")
    CHGG A 4 A_GunFlash
    CHGG B 4 A_FireBullets (5.6, 0, 1, 5, "BulletPuff")
    CHGG B 0 A_ReFire
    goto Ready
  Flash:
    CHGF A 4 bright A_Light1
    CHGF B 5 bright A_Light2
    CHGF A 0 bright A_Light0
    stop
  Spawn:
    MGUN A -1
    stop
  }
}