Classes:Clink

From ZDoom Wiki

Sabreclaw
Actor type	Monster	Game
DoomEd Number	90	Class Name	Clink
Spawn ID	1	Identifier	T_CLINK

Classes: Clink

The sabreclaw is a mechano-magical being that has a blade for a right arm. It has no ranged attack, but is fast and will cause moderate damage if it is allowed to slice its target repeatedly. They can be considered Heretic's equivalent to the demon from Doom.

DECORATE definition

ACTOR Clink 90
{
  Game Heretic
  SpawnID 1
  Health 150
  Radius 20
  Height 64
  Mass 75
  Speed 14
  Painchance 32
  Monster
  +NOBLOOD
  +FLOORCLIP
  SeeSound "clink/sight"
  AttackSound "clink/attack"
  PainSound "clink/pain"
  DeathSound "clink/death"
  ActiveSound "clink/active"
  Obituary "$OB_CLINK" // "%o was slashed by a sabreclaw."
  DropItem "SkullRodAmmo", 84, 20    
  States
  {
  Spawn:
    CLNK AB 10 A_Look
    Loop
  See:
    CLNK ABCD 3 A_Chase
    Loop
  Melee:
    CLNK E 5 A_FaceTarget
    CLNK F 4 A_FaceTarget
    CLNK G 7 A_CustomMeleeAttack(random[ClinkAttack](3,9), "clink/attack", "clink/attack")
    Goto See
  Pain:
    CLNK H 3
    CLNK H 3 A_Pain
    Goto See
  Death:
    CLNK IJ 6
    CLNK K 5 A_Scream
    CLNK L 5 A_NoBlocking
    CLNK MN 5
    CLNK O -1
    Stop
  }
}