Classes:Cyberdemon

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Cyberdemon
Actor type	Monster	Game
DoomEd Number	16	Class Name	Cyberdemon
Spawn ID	114	Identifier	T_CYBERDEMON

Classes: Cyberdemon

With 4000 health, the Cyberdemon is the strongest enemy in Doom. They can take as many as 4 BFG shots to kill; with lesser weapons this can require a lot of strafing around to dodge his rockets. It's recommended also to keep away from the walls in their presence as their rockets often inflict a lot of splash damage. As Cyberdemons do not have RAISE states, they cannot be resurrected by Arch-Viles, nor do they respawn in NIGHTMARE! skill difficulty.

DECORATE definition

actor Cyberdemon 16
{
  spawnid 114
  obituary "%o was splattered by a cyberdemon."
  health 4000
  radius 40
  height 110
  mass 1000
  speed 16
  painchance 20
  seesound "cyber/sight"
  painsound "cyber/pain"
  deathsound "cyber/death"
  activesound "cyber/active"
  MONSTER
  +BOSS
  +FLOORCLIP
  +NORADIUSDMG
  +DONTMORPH
  +MISSILEMORE
  states
  {
  Spawn:
    CYBR AB 10 A_Look
    loop
  See:
    CYBR A 3 A_Hoof
    CYBR ABBCC 3 A_Chase
    CYBR D 3 A_Metal
    CYBR D 3
    loop
  Missile:
    CYBR E 6 A_FaceTarget
    CYBR F 12 A_CyberAttack // See Rocket
    CYBR E 12 A_FaceTarget
    CYBR F 12 A_CyberAttack
    CYBR E 12 A_FaceTarget
    CYBR F 12 A_CyberAttack
    goto See
  Pain:
    CYBR G 10 A_Pain
    goto See
  Death:
    CYBR H 10
    CYBR I 10 A_Scream
    CYBR JKL 10
    CYBR M 10 A_NoBlocking
    CYBR NO 10
    CYBR P 30
    CYBR P -1 A_BossDeath
  }
}