Classes:HereticPlayer

From ZDoom Wiki

Corvus
Actor type	Player	Game
DoomEd Number	None	Class Name	HereticPlayer

Classes: PlayerPawn → HereticPlayer

Character Summary

The hero of Heretic, Corvus is a member of the tribe of Sidhe Elves on the world of Parthoris. After the massacre of the Sidhe at the hands of D'Sparil's minions, most of the survivors fled into hiding. Only Corvus set forth in search of vengeance, taking only a staff and an elvenwand to combat his foes.

After the events of Heretic, he is lost in the "Outer Worlds" for an undisclosed amount of time, some believe to be several decades or even several hundred years. Corvus finally returns to Silverspring in Heretic II, only to learn that a threat greater than D'Sparil has already begun to cause the denizens of the world to go mad one by one...

His name is derived from Corvus Corax, which is the scientific name for the Common Raven.

Additionally, Corvus's appearance is different between both games. In the first game, he appears as a cloaked man wielding a staff, and looks a lot more mysterious, while in Heretic II, he has a thin, but toned build, and does not wear any upper clothing or a cloak. His staff also now has a blade on the end, like a polearm.

DECORATE Definition

ACTOR HereticPlayer : PlayerPawn
{
  Health 100
  Radius 16
  Height 56
  Mass 100
  Painchance 255
  Speed 1
  Player.ColorRange 225, 240
  Player.DisplayName "Corvus"
  Player.StartItem "GoldWand"
  Player.StartItem "Staff"
  Player.StartItem "GoldWandAmmo", 50
  States
  {
  Spawn:
    PLAY A -1
    Stop
  See:
    PLAY ABCD 4
    Loop
  Melee:
  Missile:
    PLAY F 6 BRIGHT
    PLAY E 12
    Goto Spawn
  Pain:
    PLAY G 4
    PLAY G 4 A_Pain
    Goto Spawn
  Death:
    PLAY H 6 A_PlayerSkinCheck("AltSkinDeath")
    PLAY I 6 A_PlayerScream
    PLAY JK 6
    PLAY L 6 A_NoBlocking
    PLAY MNO 6
    PLAY P -1
    Stop
  XDeath:
    PLAY Q 0 A_PlayerSkinCheck("AltSkinXDeath")
    PLAY Q 5 A_PlayerScream
    PLAY R 0 A_NoBlocking
    PLAY R 5 A_SkullPop
    PLAY STUVWX 5
    PLAY Y -1
    Stop
  Burn:
    FDTH A 5 BRIGHT A_PlaySound("*burndeath")
    FDTH B 4 BRIGHT
    FDTH C 5 BRIGHT
    FDTH D 4 BRIGHT A_PlayerScream
    FDTH E 5 BRIGHT
    FDTH F 4 BRIGHT
    FDTH G 5 BRIGHT A_PlaySound("*burndeath")
    FDTH H 4 BRIGHT
    FDTH I 5 BRIGHT
    FDTH J 4 BRIGHT
    FDTH K 5 BRIGHT
    FDTH L 4 BRIGHT
    FDTH M 5 BRIGHT
    FDTH N 4 BRIGHT
    FDTH O 5 BRIGHT A_NoBlocking
    FDTH P 4 BRIGHT
    FDTH Q 5 BRIGHT
    FDTH R 4 BRIGHT
    ACLO E 35 A_CheckPlayerDone
    Wait
  AltSkinDeath:	
    PLAY H 10
    PLAY I 10 A_PlayerScream
    PLAY J 10 A_NoBlocking
    PLAY KLM 10
    PLAY N -1
    Stop
  AltSkinXDeath:
    PLAY O 5
    PLAY P 5 A_XScream
    PLAY Q 5 A_NoBlocking
    PLAY RSTUV 5
    PLAY W -1
    Stop
  }
}				

// The player's skull -------------------------------------------------------

ACTOR BloodySkull : PlayerChunk
{
  Radius 4
  Height 4
  +NOBLOCKMAP
  +DROPOFF
  +LOWGRAVITY
  +CANNOTPUSH
  +SKYEXPLODE
  +NOBLOCKMONST
  +NOSKIN
  States
  {
  Spawn:
    BSKL A 0
    BSKL ABCDE 5 A_CheckFloor("Hit")
    Goto Spawn+1
  Hit:
    BSKL F 16 A_CheckPlayerDone
    Wait
  }
}