Classes:PainElemental

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Pain Elemental
Actor type	Monster	Game
DoomEd Number	71	Class Name	PainElemental
Spawn ID	115	Identifier	T_PAINELEMENTAL

Classes: PainElemental

Pain Elementals are similar in appearance to cacodemons, but are brown. The Pain Elemental is unique in that it doesn't have an attack of its own, rather it spawns Lost Souls to do its bidding for them. Note that when a Pain Elemental dies 3 Lost Souls spawn to replace it.

DECORATE definition

actor PainElemental 71
{
  spawnid 115
  health 400
  radius 31
  height 56
  mass 400
  speed 8
  painchance 128
  seesound "pain/sight"
  painsound "pain/pain"
  deathsound "pain/death"
  activesound "pain/active"
  MONSTER
  +FLOAT
  +NOGRAVITY
  states
  {
  Spawn:
    PAIN A 10 A_Look
    loop
  See:
    PAIN AABBCC 3 A_Chase
    loop
  Missile:
    PAIN DE 5 A_FaceTarget
    PAIN F 5 bright A_FaceTarget
    PAIN F 0 bright A_PainAttack    // See LostSoul
    goto See
  Pain:
    PAIN G 6
    PAIN G 6 A_Pain
    goto See
  Death:
    PAIN H 8 bright
    PAIN I 8 bright A_Scream
    PAIN JK 8 bright
    PAIN L 8 bright A_PainDie       // See LostSoul
    PAIN M 8 bright
    stop
  Raise:
    PAIN MLKJIH 8
    goto See
  }
}