Classes:Reaver

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Reaver
Actor type	Monster	Game
DoomEd Number	3001	Class Name	Reaver

Classes: Reaver
Reavers are enemies from Strife. From range, they shoot bullets at you, which can take you quite some health, so be careful. If they get close, they attempt to slice you with a blade. They don't have much health but can deal some good damage, especially in groups.

DECORATE definition

ACTOR Reaver 3001
{
  Game Strife
  Health 150
  Painchance 128
  Speed 12
  Radius 20
  Height 60
  Monster
  +NOBLOOD
  +INCOMBAT
  MinMissileChance 150
  MaxDropoffHeight 32
  Mass 500
  ConversationID 52, -1, -1
  SeeSound "reaver/sight"
  PainSound "reaver/pain"
  DeathSound "reaver/death"
  ActiveSound "reaver/active"
  HitObituary "$OB_REAVERHIT" // "%o was sliced open by a Reaver."
  Obituary "$OB_REAVER" // "%o was shot down by a Reaver."
  
  action native A_ReaverRanged();
  
  States
  {
  Spawn:
    ROB1 A 10 A_Look
    Loop
  See:
    ROB1 BBCCDDEE 3 A_Chase
    Loop
  Melee:
    ROB1 H 6 A_FaceTarget
    ROB1 I 8 A_CustomMeleeAttack(random[ReaverMelee](1,8)*3, "reaver/blade")
    ROB1 H 6
    Goto See
  Missile:
    ROB1 F 8 A_FaceTarget
    ROB1 G 11 BRIGHT A_ReaverRanged
    Goto See
  Pain:
    ROB1 A 2
    ROB1 A 2 A_Pain
    Goto See
  Death:
    ROB1 J 6
    ROB1 K 6 A_Scream
    ROB1 L 5
    ROB1 M 5 A_NoBlocking
    ROB1 NOP 5
    ROB1 Q 6 A_Explode(32,32,1,1)
    ROB1 R -1
    Stop
  XDeath:
    ROB1 L 5 A_TossGib
    ROB1 M 5 A_Scream
    ROB1 N 5 A_TossGib
    ROB1 O 5 A_NoBlocking
    ROB1 P 5 A_TossGib
    Goto Death+7
  }
}