Classes:Rebel

From ZDoom Wiki

Rebel
Actor type	Monster	Game
DoomEd Number	None	Class Name	Rebel

Classes: StrifeHumanoid→Rebel

 →Rebel1
 →Rebel2
 →Rebel3
 →Rebel4
 →Rebel5
 →Rebel6
Soldiers of The Front, battling the oppressive Order. Similar to Acolytes, but faster and more fragile. They fight on the player's side.

This paticular actor is used as a base actor for the other Rebel variants, and is summoned by the Teleporter Beacon item.

DECORATE definition

ACTOR Rebel : StrifeHumanoid
{
  Health 60
  Painchance 250
  Speed 8
  Radius 20
  Height 56
  Monster
  +FRIENDLY
  -COUNTKILL
  +NOSPLASHALERT
  MinMissileChance 150
  Tag "Rebel"
  SeeSound "rebel/sight"
  PainSound "rebel/pain"
  DeathSound "rebel/death"
  ActiveSound "rebel/active"
  Obituary "$OB_REBEL" // "%o was gunned down by a Rebel."
  States
  {
  Spawn:
    HMN1 P 5 A_Look2
    Loop
    HMN1 Q 8
    Loop
    HMN1 R 8
    Loop
    HMN1 ABCDABCD 6 A_Wander
    Loop
  See:
    HMN1 AABBCCDD 3 A_Chase
    Loop
  Missile:
    HMN1 E 10 A_FaceTarget
    HMN1 F 10 BRIGHT A_ShootGun
    HMN1 E 10 A_ShootGun
    Goto See
  Pain:
    HMN1 O 3
    HMN1 O 3 A_Pain
    Goto See
  Death:
    HMN1 G 5
    HMN1 H 5 A_Scream
    HMN1 I 3 A_NoBlocking
    HMN1 J 4
    HMN1 KLM 3
    HMN1 N -1
    Stop
  XDeath:
    RGIB A 4 A_TossGib
    RGIB B 4 A_XScream
    RGIB C 3 A_NoBlocking
    RGIB DEF 3 A_TossGib
    RGIB G 3
    RGIB H 1400
    Stop
  }
}