Classes:StrifePlayer

From ZDoom Wiki

Rebel mercenary
Actor type	Player	Game
DoomEd Number	None	Class Name	StrifePlayer

Classes: PlayerPawn → StrifePlayer

The nameless protagonist of Strife. He's fairly similar in skills to the other PlayerPawns, except that he can improve his skills and stats throughout the game by earning stamina upgrades and accuracy upgrades.

DECORATE definition

ACTOR StrifePlayer : PlayerPawn
{
  Health 100
  Radius 18
  Height 56
  Mass 100
  PainChance 255
  Speed 1
  MaxStepHeight 16
  Player.ColorRange 128, 143
  Player.DisplayName "Rebel"
  Player.StartItem "PunchDagger"
  
  action native A_ItBurnsItBurns();
  action native A_CrispyPlayer();
  action native A_HandLower();
  
  States
  {
  Spawn:
    PLAY A -1
    Stop
  See:
    PLAY ABCD 4 
    Loop
  Missile:
    PLAY E 12
    Goto Spawn
  Melee:
    PLAY F 6
    Goto Missile
  Death:
    PLAY H 3
    PLAY I 3 A_PlayerScream
    PLAY J 3 A_NoBlocking
    PLAY KLMNO 4
    PLAY P -1
    Stop
  XDeath:
    RGIB A 5 A_TossGib
    RGIB B 5 A_XScream
    RGIB C 5 A_NoBlocking
    RGIB DEFG 5 A_TossGib
    RGIB H -1 A_TossGib
  Burn:
    BURN A 3 Bright A_ItBurnsItBurns
    BURN B 3 Bright A_DropFire
    BURN C 3 Bright A_Wander
    BURN D 3 Bright A_NoBlocking
    BURN E 5 Bright A_DropFire
    BURN FGH 5 Bright A_Wander
    BURN I 5 Bright A_DropFire
    BURN JKL 5 Bright A_Wander
    BURN M 5 Bright A_DropFire
    BURN N 5 Bright A_CrispyPlayer
    BURN OPQPQ 5 Bright
    BURN RSTU 7 Bright
    BURN V -1
    Stop
  Disintegrate:
    DISR A 5 A_PlaySoundEx("misc/disruptordeath", "Voice")
    DISR BC 5
    DISR D 5 A_NoBlocking
    DISR EF 5
    DISR GHIJ 4
    MEAT D -1
    Stop
  Firehands:
    WAVE ABCD 3
    Loop
  Firehandslower:
    WAVE ABCD 3 A_HandLower
    Loop
  }
}