Classes:SuperShotgun

From ZDoom Wiki

Super shotgun
Actor type	Weapon	Game
DoomEd Number	82	Class Name	SuperShotgun
Spawn ID	33	Identifier	T_SUPERSHOTGUN

Classes: Inventory→Weapon→DoomWeapon→SuperShotgun

The super shotgun. Also known as the double-barreled shotgun. A powerful hitscan weapon and has a large spread. Uses shells for ammo. This is the only weapon to not appear in the original Doom.

DECORATE definition

actor SuperShotgun : DoomWeapon 82
{
  Game Doom
  SpawnID 33
  Weapon.SelectionOrder 400
  Weapon.AmmoUse 2
  Weapon.AmmoGive 8
  Weapon.AmmoType "Shell"
  Inventory.PickupMessage "$GOTSHOTGUN2" // "You got the super shotgun!"
  Obituary "$OB_MPSSHOTGUN" // "%o was splattered by %k's super shotgun."
  States
  {
  Ready:
    SHT2 A 1 A_WeaponReady
    Loop
  Deselect:
    SHT2 A 1 A_Lower
    Loop
  Select:
    SHT2 A 1 A_Raise
    Loop
  Fire:
    SHT2 A 3
    SHT2 A 7 A_FireShotgun2
    SHT2 B 7
    SHT2 C 7 A_CheckReload
    SHT2 D 7 A_OpenShotgun2
    SHT2 E 7
    SHT2 F 7 A_LoadShotgun2
    SHT2 G 6
    SHT2 H 6 A_CloseShotgun2
    SHT2 A 5 A_ReFire
    Goto Ready
  // unused states
    SHT2 B 7
    SHT2 A 3
    Goto Deselect
  Flash:
    SHT2 I 4 Bright A_Light1
    SHT2 J 3 Bright A_Light2
    Goto LightDone
  Spawn:
    SGN2 A -1
    Stop
  }
}