Classes:SuperShotgunGuy

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Super-shotgun zombie
Actor type	Monster	Game
DoomEd Number	5005	Class Name	SuperShotgunGuy
Spawn ID	157	Identifier	T_SSGGUY

Warning: This class is a Skulltag-specific actor that is not included in ZDoom!

Classes: SuperShotgunGuy

Rounding up the family of zombies with hitscan weapons, this obese former human uses a SuperShotgun.

DECORATE definition

ACTOR SuperShotgunGuy 5005
{
  Game Doom
  SpawnID 157
  Health 120
  Radius 20
  Height 56
  Mass 100
  Speed 8
  PainChance 170
  SeeSound "chainguy/sight"
  PainSound "chainguy/pain"
  DeathSound "chainguy/death"
  ActiveSound "chainguy/active"
  AttackSound "ssgguy/attack"
  MONSTER
  +FLOORCLIP
  Obituary "$OB_SSGGUY" // "%o was jacked by a super shotgun guy."
  DropItem "SuperShotgun"
  States
  {
    Spawn:
      GPOS AB 10 A_Look
      Loop
    See:
      GPOS AABBCCDD 4 A_Chase
      Loop
    Missile:
      GPOS E 10 A_FaceTarget
      GPOS F 8 Bright A_CustomBulletAttack(8, 7, 7, 5, "BulletPuff")
      GPOS E 8
      Goto See
    Pain:
      GPOS G 3
      GPOS G 3 A_Pain
      Goto See
    Death:
      GPOS H 5
      GPOS I 5 A_Scream
      GPOS J 5 A_NoBlocking
      GPOS KLM 5
      GPOS N -1
      Stop
    XDeath:
      GPOS O 5
      GPOS P 5 A_XScream
      GPOS Q 5 A_NoBlocking
      GPOS RS 5
      GPOS T -1
      Stop
    Raise:
      GPOS LKJIH 5
      Goto See
  }
}