Classes:WolfensteinSS

From ZDoom Wiki

Wolfenstein SS
Actor type	Monster	Game
DoomEd Number	84	Class Name	WolfensteinSS
Spawn ID	116	Identifier	T_WOLFSS

Classes: WolfensteinSS

The Wolfenstein SS guard ("WolfSS") is an enemy from Wolfenstein 3D, which appears in the secret levels of Doom 2. He is armed with a machine gun and leaves a clip after death.

Difficulty levels in Wolfenstein 3D were implemented by controlling the speed at which the enemies react and fire. For Doom 2, id simply placed 2-4 of these enemies everywhere that one guard appeared in Wolfenstein. Unfortunately, because enemies in Doom can also hurt each other, this just made them tend to infight with each other more.

The attack frames for this enemy are single-rotation only (as in Wolfenstein 3D), so that he always appears to be firing directly at the player viewing him, no matter what direction he's actually shooting in.

DECORATE definition

actor WolfensteinSS 84
{
  spawnid 116
  obituary "%o met a Nazi."
  health 50
  radius 20
  height 56
  mass 100
  speed 8
  painchance 170
  seesound "wolfss/sight"
  attacksound "wolfss/attack"
  painsound "wolfss/pain"
  deathsound "wolfss/death"
  activesound "wolfss/active"
  dropitem "Clip" 256
  MONSTER
  +FLOORCLIP
  states
  {
  Spawn:
    SSWV AB 10 A_Look
    loop
  See:
    SSWV AABBCCDD 3 A_Chase
    loop
  Missile:
    SSWV EF 10 A_FaceTarget
    SSWV G 4 bright A_CPosAttack
    SSWV F 6 A_FaceTarget
    SSWV G 4 bright A_CPosAttack
    SSWV F 1 A_CPosRefire
    goto Missile+1
  Pain:
    SSWV H 3
    SSWV H 3 A_Pain
    goto See
  Death:
    SSWV I 5
    SSWV J 5 A_Scream
    SSWV K 5 A_NoBlocking
    SSWV L 5
    SSWV M -1
    stop
  XDeath:
    SSWV N 5
    SSWV O 5 A_XScream
    SSWV P 5 A_NoBlocking
    SSWV QRSTU 5
    SSWV V -1
    stop
  Raise:
    SSWV MLKJI 5
    goto See
  }
}