Classes:DoomImp

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do not need to copy that actor, since it is already defined. In fact, it's not just useless, it's actually harmful as it can cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them. There is only one exception: if what you want is changing Ammo capacity, you need to create a new type from Ammo.

Imp
Actor type	Monster	Game
DoomEd Number	3001	Class Name	DoomImp
Spawn ID	5	Identifier	T_IMP

Classes: DoomImp
 →DeadDoomImp
 →StealthDoomImp
 →DarkImp (Skulltag only: not supported by ZDoom)

Imps are common enemies throughout the game. They slash up close which is a pain because they always seem to get close to you when there's more than one. The fireballs they throw do average damage. Luckily they don't have that much health, and one shotgun blast can put them to sleep.

DECORATE definition

actor DoomImp 3001
{
  spawnid 5
  obituary "%o was burned by an imp."
  hitobituary "%o was slashed by an imp."
  health 60
  radius 20
  height 56
  mass 100
  speed 8
  painchance 200
  seesound "imp/sight"
  painsound "imp/pain"
  deathsound "imp/death"
  activesound "imp/active"
  MONSTER
  +FLOORCLIP
  states
  {
  Spawn:
    TROO AB 10 A_Look
    loop
  See:
    TROO AABBCCDD 3 A_Chase
    loop
  Melee:
  Missile:
    TROO EF 8 A_FaceTarget
    TROO G 6 A_TroopAttack  // See DoomImpBall
    goto See
  Pain:
    TROO H 2
    TROO H 2 A_Pain
    goto See
  Death:
    TROO I 8
    TROO J 8 A_Scream
    TROO K 6
    TROO L 6 A_NoBlocking
    TROO M -1
    stop
  XDeath:
    TROO N 5
    TROO O 5 A_XScream
    TROO P 5
    TROO Q 5 A_NoBlocking
    TROO RST 5
    TROO U -1
    stop
  Raise:
    TROO ML 8
    TROO KJI 6
    goto See
  }
}