Classes:Acolyte

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Acolyte
Actor type	Monster	Game	(Strife)
DoomEd Number	None	Class Name	Acolyte

Classes: Actor → StrifeHumanoid → Acolyte
 →AcolyteBlue
 →AcolyteDGreen
 →AcolyteGold
 →AcolyteGray
 →AcolyteLGreen
 →AcolyteRed
 →AcolyteRust
 →AcolyteShadow
 →AcolyteTan
 →AcolyteToBe
The foot soldiers of The Order, Acolytes are "converted" humans armed with Assault Rifles, and in some cases Shadow Armor, making them Shadow Acolytes. They generally only attack you if the alarm has been sounded.

DECORATE definition

ACTOR Acolyte : StrifeHumanoid
{
  Health 70
  PainChance 150
  Speed 7
  Radius 24
  Height 64
  Mass 400
  Monster
  +SEESDAGGERS
  +NOSPLASHALERT
  +FLOORCLIP
  +NEVERRESPAWN
  MinMissileChance 150
  Tag "$TAG_ACOLYTE" // "ACOLYTE"
  SeeSound "acolyte/sight"
  PainSound "acolyte/pain"
  AttackSound "acolyte/rifle"
  DeathSound "acolyte/death"
  ActiveSound "acolyte/active"
  Obituary "$OB_ACOLYTE" // "%o was zealously shot down by an Acolyte."

  action native A_BeShadowyFoe();
  action native A_AcolyteBits();
  action native A_AcolyteDie();

  States
  {
  Spawn:
    AGRD A 5 A_Look2
    Wait
    AGRD B 8 A_ClearShadow
    Loop
    AGRD D 8
    Loop
    AGRD ABCDABCD 5 A_Wander
    Loop
  See:
    AGRD A 6 Fast Slow A_AcolyteBits
    AGRD BCD 6 Fast Slow A_Chase
    Loop
  Missile:
    AGRD E 8 Fast Slow A_FaceTarget
    AGRD FE 4 Fast Slow A_ShootGun
    AGRD F 6 Fast Slow A_ShootGun
    Goto See
  Pain:
    AGRD O 8 Fast Slow A_Pain
    Goto See
  Death:
    AGRD G 4
    AGRD H 4 A_Scream
    AGRD I 4
    AGRD J 3
    AGRD K 3 A_NoBlocking
    AGRD L 3
    AGRD M 3 A_AcolyteDie
    AGRD N -1
    Stop
  XDeath:
    GIBS A 5 A_NoBlocking
    GIBS BC 5 A_TossGib
    GIBS D 4 A_TossGib
    GIBS E 4 A_XScream
    GIBS F 4 A_TossGib
    GIBS GH 4
    GIBS I 5
    GIBS J 5 A_AcolyteDie
    GIBS K 5
    GIBS L 1400
    Stop
  }
}