Classes:Beggar

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Beggar
Actor type	Monster	Game	(Strife)
DoomEd Number	None	Class Name	Beggar

Classes: StrifeHumanoid→Beggar
 →Beggar1
 →Beggar2
 →Beggar3
 →Beggar4
 →Beggar5

The base class for all beggars from Strife. It is not used directly in the game.

DECORATE definition

ACTOR Beggar : StrifeHumanoid
{
  Health 20
  PainChance 250
  Speed 3
  Radius 20
  Height 56
  Monster
  +JUSTHIT
  -COUNTKILL
  +NOSPLASHALERT
  MinMissileChance 150
  Tag "$TAG_BEGGAR" // "Beggar"
  MaxStepHeight 16
  MaxDropoffHeight 32
  HitObituary "$OB_BEGGAR" // "%o was beaten to death by the poor."
  AttackSound "beggar/attack"
  PainSound "beggar/pain"
  DeathSound "beggar/death"
  States
  {
  Spawn:
    BEGR A 10 A_Look
    Loop
  See:
    BEGR AABBCC 4 A_Wander
    Loop
  Melee:
    BEGR D 8
    BEGR D 8 A_CustomMeleeAttack(2*random[PeasantAttack](1, 5)+2)
    BEGR E 1 A_Chase
    BEGR D 8 A_SentinelRefire
    Loop
  Pain:
    BEGR A 3 A_Pain
    BEGR A 3 A_Chase
    Goto Melee
  Death:
    BEGR F 4
    BEGR G 4 A_Scream
    BEGR H 4
    BEGR I 4 A_NoBlocking
    BEGR JKLM 4
    BEGR N -1
    Stop
  XDeath:
    BEGR F 5 A_TossGib
    GIBS M 5 A_TossGib
    GIBS N 5 A_XScream
    GIBS O 5 A_NoBlocking
    GIBS PQRST 4 A_TossGib
    GIBS U 5
    GIBS V 1400
    Stop
  }
}