Classes:Fatso

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

Mancubus
Actor type	Monster	Game	(Doom2)
DoomEd Number	67	Class Name	Fatso
Spawn ID	112	Identifier	T_MANCUBUS

Classes: Fatso
 →StealthFatso

The mancubus has a lot of health so killing them won't be easy, especially when they can shoot 6 fireballs at a time every time they attack! The fireballs take lots of health off too, and can be hard to dodge because they are huge. Get lots of cover before challenging these huge things.

ZScript definition

Note: The ZScript definition below is for reference and may be different in the current version of GZDoom.The most up-to-date version of this code can be found on GZDoom GitHub.

class Fatso : Actor
{
	Default
	{
		Health 600;
		Radius 48;
		Height 64;
		Mass 1000;
		Speed 8;
		PainChance 80;
		Monster;
		+FLOORCLIP
		+BOSSDEATH
		SeeSound "fatso/sight";
		PainSound "fatso/pain";
		DeathSound "fatso/death";
		ActiveSound "fatso/active";
		Obituary "$OB_FATSO";
		Tag "$FN_MANCU";
	}
	States
	{
	Spawn:
		FATT AB 15 A_Look;
		Loop;
	See:
		FATT AABBCCDDEEFF 4 A_Chase;
		Loop;
	Missile:
		FATT G 20 A_FatRaise;
		FATT H 10 BRIGHT A_FatAttack1;
		FATT IG 5 A_FaceTarget;
		FATT H 10 BRIGHT A_FatAttack2;
		FATT IG 5 A_FaceTarget;
		FATT H 10 BRIGHT A_FatAttack3;
		FATT IG 5 A_FaceTarget;
		Goto See;
	Pain:
		FATT J 3;
		FATT J 3 A_Pain;
		Goto See;
	Death:
		FATT K 6;
		FATT L 6 A_Scream;
		FATT M 6 A_NoBlocking;
		FATT NOPQRS 6;
		FATT T -1 A_BossDeath;
		Stop;
	 Raise:
		FATT R 5;
		FATT QPONMLK 5;
		Goto See;
	}
}

DECORATE definition

Note: This is legacy code, kept for archival purposes only. DECORATE is deprecated in GZDoom and is completely superseded by ZScript. GZDoom internally uses the ZScript definition above.

ACTOR Fatso
{
  Health 600
  Radius 48
  Height 64
  Mass 1000
  Speed 8
  PainChance 80
  Monster
  +FLOORCLIP
  +BOSSDEATH
  SeeSound "fatso/sight"
  PainSound "fatso/pain"
  DeathSound "fatso/death"
  ActiveSound "fatso/active"
  Obituary "$OB_FATSO"
  States
  {
  Spawn:
    FATT AB 15 A_Look
    Loop
  See:
    FATT AABBCCDDEEFF 4 A_Chase
    Loop
  Missile:
    FATT G 20 A_FatRaise
    FATT H 10 Bright A_FatAttack1
    FATT IG 5 A_FaceTarget
    FATT H 10 Bright A_FatAttack2
    FATT IG 5 A_FaceTarget
    FATT H 10 Bright A_FatAttack3
    FATT IG 5 A_FaceTarget
    Goto See
  Pain:
    FATT J 3
    FATT J 3 A_Pain
    Goto See
  Death:
    FATT K 6
    FATT L 6 A_Scream
    FATT M 6 A_NoBlocking
    FATT NOPQRS 6
    FATT T -1 A_BossDeath
    Stop
  Raise:
    FATT R 5
    FATT QPONMLK 5
    Goto See
  }
}