Classes:SpiderMastermind

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

Spider Mastermind
Actor type	Monster	Game	(Doom)
DoomEd Number	7	Class Name	SpiderMastermind
Spawn ID	7	Identifier	T_SPIDERMASTERMIND

Classes: SpiderMastermind

The Spider Mastermind (a.k.a. the Spiderdemon) is the endboss of Doom. Although with 3000 HPs, it doesn't have as much health as the Cyberdemon, but its chaingun is essentially a sped-up version of Sergeant's shotgun (firing 3 bullets per shot), making this enemy especially deadly.

Doom 2 manual jokingly describes Spider Mastermind as Arachnotron's "mom" and implies this demon is actually female.

ZScript definition

Note: The ZScript definition below is for reference and may be different in the current version of GZDoom.The most up-to-date version of this code can be found on GZDoom GitHub.

class SpiderMastermind : Actor
{
	Default
	{
		Health 3000;
		Radius 128;
		Height 100;
		Mass 1000;
		Speed 12;
		PainChance 40;
		Monster;
		+BOSS
		+MISSILEMORE
		+FLOORCLIP
		+NORADIUSDMG
		+DONTMORPH
		+BOSSDEATH
		SeeSound "spider/sight";
		AttackSound "spider/attack";
		PainSound "spider/pain";
		DeathSound "spider/death";
		ActiveSound "spider/active";
		Obituary "$OB_SPIDER";
		Tag "$FN_SPIDER";
	}
	States
	{
	Spawn:
		SPID AB 10 A_Look;
		Loop;
	See:
		SPID A 3 A_Metal;
		SPID ABB 3 A_Chase;
		SPID C 3 A_Metal;
		SPID CDD 3 A_Chase;
		SPID E 3 A_Metal;
		SPID EFF 3 A_Chase;
		Loop;
	Missile:
		SPID A 20 BRIGHT A_FaceTarget;
		SPID G 4 BRIGHT A_SPosAttackUseAtkSound;
		SPID H 4 BRIGHT A_SPosAttackUseAtkSound;
		SPID H 1 BRIGHT A_SpidRefire;
		Goto Missile+1;
	Pain:
		SPID I 3;
		SPID I 3 A_Pain;
		Goto See;
	Death:
		SPID J 20 A_Scream;
		SPID K 10 A_NoBlocking;
		SPID LMNOPQR 10;
		SPID S 30;
		SPID S -1 A_BossDeath;
		Stop;
	}
}

DECORATE definition

Note: This is legacy code, kept for archival purposes only. DECORATE is deprecated in GZDoom and is completely superseded by ZScript. GZDoom internally uses the ZScript definition above.

ACTOR SpiderMastermind
{
  Health 3000
  Radius 128
  Height 100
  Mass 1000
  Speed 12
  PainChance 40
  Monster
  MinMissileChance 160
  +BOSS
  +MISSILEMORE
  +FLOORCLIP
  +NORADIUSDMG
  +DONTMORPH
  +BOSSDEATH
  SeeSound "spider/sight"
  AttackSound "spider/attack"
  PainSound "spider/pain"
  DeathSound "spider/death"
  ActiveSound "spider/active"
  Obituary "$OB_SPIDER"
  States
  {
  Spawn:
    SPID AB 10 A_Look
    Loop
  See:
    SPID A 3 A_Metal
    SPID ABB 3 A_Chase
    SPID C 3 A_Metal
    SPID CDD 3 A_Chase
    SPID E 3 A_Metal
    SPID EFF 3 A_Chase
    Loop
  Missile:
    SPID A 20 Bright A_FaceTarget
    SPID G 4 Bright A_SPosAttackUseAtkSound
    SPID H 4 Bright A_SPosAttackUseAtkSound
    SPID H 1 Bright A_SpidRefire
    Goto Missile+1
  Pain:
    SPID I 3
    SPID I 3 A_Pain
    Goto See
  Death:
    SPID J 20 A_Scream
    SPID K 10 A_NoBlocking
    SPID LMNOPQR 10
    SPID S 30
    SPID S -1 A_BossDeath
    Stop
  }
}