Classes:AlienSpectre1

Note: Wait! Stop! You do not need to copy this actor's code into your project! Here's why: This actor is already defined in GZDoom, there's no reason to define it again. In fact, trying to define an actor with the same name will cause an error (because it already exists). If you want to make your own version of this actor, use inheritance. Definitions for existing actors are put on the wiki for reference purpose only.

The Programmer's spectre
Actor type	Monster	Game	(Strife)
DoomEd Number	129	Class Name	AlienSpectre1
Conversation ID	67	Puzzle Item ID	N/A

Classes: SpectralMonster→AlienSpectre1
 →AlienSpectre2
 →AlienSpectre3
 →AlienSpectre4
 →AlienSpectre5
A mysterious alien creature that possesses people, bending them to their will, and turning them into dangerous maniacs obsessed with collecting the pieces of the Sigil. They can only be damaged by the Sigil. The Programmer's spectre doesn't accompany the Programmer himself, making him vulnerable to normal weapons and allowing the player to get the first piece of the Sigil. Instead, this spectre is met later in the game, in the ruins of a temple.

DECORATE definition

ACTOR AlienSpectre1 : SpectralMonster
{
  Health 1000
  PainChance 250
  Speed 12
  Radius 64
  Height 64
  FloatSpeed 5
  Mass 1000
  MinMissileChance 150
  RenderStyle Translucent
  Alpha 0.666
  SeeSound "alienspectre/sight"
  AttackSound "alienspectre/blade"
  PainSound "alienspectre/pain"
  DeathSound "alienspectre/death"
  ActiveSound "alienspectre/active"
  Obituary "$OB_ALIENSPECTRE" // "%o was struck down by the Spectre."
  +NOGRAVITY
  +FLOAT
  +SHADOW
  +NOTDMATCH
  +DONTMORPH
  +NOBLOCKMONST
  +INCOMBAT
  +LOOKALLAROUND
  +NOICEDEATH

  action native A_AlienSpectreDeath();

  States
  {
  Spawn:
    ALN1 A 10 A_Look
    ALN1 B 10 A_SentinelBob
    Loop
  See:
    ALN1 AB 4 Bright A_Chase
    ALN1 C 4 Bright A_SentinelBob
    ALN1 DEF 4 Bright A_Chase
    ALN1 G 4 Bright A_SentinelBob
    ALN1 HIJ 4 Bright A_Chase
    ALN1 K 4 Bright A_SentinelBob
    Loop
  Melee:
    ALN1 J 4 Bright A_FaceTarget
    ALN1 I 4 Bright A_CustomMeleeAttack((random[SpectreMelee](0, 255)&9)*5)
    ALN1 H 4 Bright
    Goto See
  Missile:
    ALN1 J 4 Bright A_FaceTarget
    ALN1 I 4 Bright A_SpotLightning
    ALN1 H 4 Bright
    Goto See+10
  Pain:
    ALN1 J 2 A_Pain
    Goto See+6
  Death:
    AL1P A 6 Bright A_SpectreChunkSmall
    AL1P B 6 Bright A_Scream
    AL1P C 6 Bright A_SpectreChunkSmall
    AL1P DE 6 Bright
    AL1P F 6 Bright A_SpectreChunkSmall
    AL1P G 6 Bright
    AL1P H 6 Bright A_SpectreChunkSmall
    AL1P IJK 6 Bright
    AL1P LM 5 Bright
    AL1P N 5 Bright A_SpectreChunkLarge
    AL1P OPQ 5 Bright
    AL1P R 5 Bright A_AlienSpectreDeath
    Stop
  }
}