Classes:Inquisitor

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

Inquisitor
Actor type	Monster	Game	(Strife)
DoomEd Number	16	Class Name	Inquisitor
Conversation ID	93	Puzzle Item ID	N/A

Classes: Inquisitor
Inquisitors are huge robots with a lot of health and dangerous weaponry. From afar, they shoot bullets like the Reaver (although they do so twice in a single attack). If they get close, they fire a pair of grenades, which can be devastating if not avoided. Inquisitors are also equipped with a jetpack which allows them to fly to get to you.

DECORATE definition

ACTOR Inquisitor
{
  Health 1000
  Speed 12
  Radius 40
  Height 110
  Mass 0x7fffffff
  Monster
  +DROPOFF
  +NOBLOOD
  +BOSS
  +FLOORCLIP
  +DONTMORPH
  +NORADIUSDMG
  MaxDropOffHeight 32
  MinMissileChance 150
  SeeSound "inquisitor/sight"
  DeathSound "inquisitor/death"
  ActiveSound "inquisitor/active"
  Obituary "$OB_INQUISITOR" // "%o was sentenced by an Inquisitor."

  action native A_InquisitorWalk();
  action native A_InquisitorDecide();
  action native A_InquisitorAttack();
  action native A_InquisitorJump();
  action native A_InquisitorCheckLand();
  action native A_TossArm();
  action native A_ReaverRanged();

  States
  {
  Spawn:
    ROB3 AB 10 A_Look
    Loop
  See:
    ROB3 B 3 A_InquisitorWalk
    ROB3 B 3 A_Chase
    ROB3 CCDD 4 A_Chase
    ROB3 E 3 A_InquisitorWalk
    ROB3 E 3 A_InquisitorDecide
    Loop
  Missile:
    ROB3 A 2 A_InquisitorDecide
    ROB3 F 6 A_FaceTarget
    ROB3 G 8 Bright A_ReaverRanged
    ROB3 G 8 A_ReaverRanged
    Goto See
  Grenade:
    ROB3 K 12 A_FaceTarget
    ROB3 J 6 Bright A_InquisitorAttack
    ROB3 K 12
    Goto See
  Jump:
    ROB3 H 8 Bright A_InquisitorJump
    ROB3 I 4 Bright A_InquisitorCheckLand
    ROB3 H 4 Bright A_InquisitorCheckLand
    Goto Jump+1
  Death:
    ROB3 L 0 A_StopSoundEx("Item")
    ROB3 L 4 A_TossGib
    ROB3 M 4 A_Scream
    ROB3 N 4 A_TossGib
    ROB3 O 4 Bright A_Explode(128, 128, 1, 1)
    ROB3 P 4 Bright A_TossGib
    ROB3 Q 4 Bright A_NoBlocking
    ROB3 RSTUV 4 A_TossGib
    ROB3 W 4 Bright A_Explode(128, 128, 1, 1)
    ROB3 XY 4 Bright A_TossGib
    ROB3 Z 4 A_TossGib
    ROB3 "[" 4 A_TossGib
    ROB3 "\" 3 A_TossGib
    ROB3 "]" 3 Bright A_Explode(128, 128, 1, 1)
    RBB3 A 3 Bright A_TossArm
    RBB3 B 3 Bright A_TossGib
    RBB3 CD 3 A_TossGib
    RBB3 E -1
    Stop
  }
}