Classes:Bishop

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

Bishop
Actor type	Monster	Game	(Hexen)
DoomEd Number	114	Class Name	Bishop
Spawn ID	19	Identifier	T_BISHOP

Classes: Bishop
The dark bishops worshiping Korax, filling a similar role to the Disciples of D'Sparil. They explode when they die, and can injure nearby monsters with their death throes, even other dark bishops.

DECORATE definition

ACTOR Bishop
{
  Health 130
  Radius 22
  Height 65
  Speed 10
  PainChance 110
  Monster
  +FLOAT
  +NOGRAVITY
  +NOBLOOD
  +TELESTOMP
  +DONTOVERLAP
  +NOTARGETSWITCH
  SeeSound "BishopSight"
  AttackSound "BishopAttack"
  PainSound "BishopPain"
  DeathSound "BishopDeath"
  ActiveSound "BishopActiveSounds"
  Obituary "$OB_BISHOP"

  action native A_BishopChase();
  action native A_BishopDecide();
  action native A_BishopDoBlur();
  action native A_BishopSpawnBlur();
  action native A_BishopPainBlur();
  action native A_BishopAttack();
  action native A_BishopAttack2();

  States
  {
  Spawn:
    BISH A 10 A_Look
    Loop
  See:
    BISH A 2 A_Chase
    BISH A 2 A_BishopChase
    BISH A 2
    BISH B 2 A_BishopChase
    BISH B 2 A_Chase
    BISH B 2 A_BishopChase
    BISH A 1 A_BishopDecide
    Loop
  Blur:
    BISH A 2 A_BishopDoBlur
    BISH A 4 A_BishopSpawnBlur
    Wait
  Pain:
    BISH C 6 A_Pain
    BISH CCC 6 A_BishopPainBlur
    BISH C 0
    Goto See
  Missile:
    BISH A 3 A_FaceTarget
    BISH DE 3 A_FaceTarget
    BISH F 3 A_BishopAttack
    BISH F 5 A_BishopAttack2
    Wait
  Death:
    BISH G 6
    BISH H 6 Bright A_Scream
    BISH I 5 Bright A_NoBlocking
    BISH J 5 Bright A_Explode(random[BishopBoom](25, 40))
    BISH K 5 Bright
    BISH LM 4 Bright
    BISH N 4 A_SpawnItemEx("BishopPuff", 0, 0, 40, 0, 0, 0.5)
    BISH O 4 A_QueueCorpse
    BISH P -1
    Stop
  Ice:
    BISH X 5 A_FreezeDeath
    BISH X 1 A_FreezeDeathChunks
    Wait
  }
}