Classes:StrifeGrenadeLauncher

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

Dual grenade launcher
Actor type	Weapon	Game	(Strife)
DoomEd Number	154	Class Name	StrifeGrenadeLauncher
Conversation ID	195, 189, 193	Puzzle Item ID	N/A

Classes: Inventory→Weapon→StrifeWeapon→StrifeGrenadeLauncher
 →StrifeGrenadeLauncher2
A double barreled grenade launcher, with two modes of fire. This mode fires Explosive Grenades, which do exactly that after three or four bounces.

DECORATE definition

ACTOR StrifeGrenadeLauncher : StrifeWeapon
{
  +FLOORCLIP
  Weapon.SelectionOrder 2400
  Weapon.AmmoUse1 1
  Weapon.AmmoGive1 12
  Weapon.AmmoType1 "HEGrenadeRounds"
  Weapon.SisterWeapon "StrifeGrenadeLauncher2"
  Inventory.Icon "GRNDA0"
  Tag "$TAG_GLAUNCHER1" // "Grenade Launcher"
  Inventory.PickupMessage "$TXT_GLAUNCHER" // "You picked up the Grenade launcher."

  action native A_FireGrenade(class<Actor> grenadetype, float angleofs, state flash);

  States
  {
  Spawn:
    GRND A -1
    Stop
  Ready:
    GREN A 1 A_WeaponReady
    Loop
  Deselect:
    GREN A 1 A_Lower
    Loop
  Select:
    GREN A 1 A_Raise
    Loop
  Fire:
    GREN A 5 A_FireGrenade("HEGrenade", -90, "Flash")
    GREN B 10
    GREN A 5 A_FireGrenade("HEGrenade", 90, "Flash2")
    GREN C 10
    GREN A 0 A_ReFire
    Goto Ready
  Flash:
    GREF A 5 Bright A_Light1
    Goto LightDone
  Flash2:
    GREF B 5 Bright A_Light2
    Goto LightDone
  }
}