Classes:Wizard

Note: Wait! Stop! Before you copy this actor's definition into your mod, remember the following things: You do NOT need to copy that actor, since it is already defined. In fact, it's not just useless, it will cause problems. If you want to modify it, or use a modified version, using inheritance is the way to go. The actor definitions here are put on the wiki for reference purpose only. Learn from them, don't copy them.

Disciple of D'Sparil
Actor type	Monster	Game	(Heretic)
DoomEd Number	15	Class Name	Wizard
Spawn ID	19	Identifier	T_WIZARD

Classes: Wizard
The Disciples are sinister wizards wearing a dark hooded robe, probably undead. They shoot three purple halo-like projectiles on a wide fan, a behavior which can be used to induce infighting. D'Sparil can summon them by pairs.

DECORATE definition

ACTOR Wizard
{
  Health 180
  Radius 16
  Height 68
  Mass 100
  Speed 12
  PainChance 64
  Monster
  +FLOAT
  +NOGRAVITY
  +DONTOVERLAP
  SeeSound "wizard/sight"
  AttackSound "wizard/attack"
  PainSound "wizard/pain"
  DeathSound "wizard/death"
  ActiveSound "wizard/active"
  Obituary "$OB_WIZARD"
  HitObituary "$OB_WIZARDHIT"
  DropItem "BlasterAmmo", 84, 10
  DropItem "ArtiTomeOfPower", 4, 0

  action native A_GhostOff();
  action native A_WizAtk1();
  action native A_WizAtk2();
  action native A_WizAtk3();

  States
  {
  Spawn:
    WZRD AB 10 A_Look
    Loop
  See:
    WZRD A 3 A_Chase
    WZRD A 4 A_Chase
    WZRD A 3 A_Chase
    WZRD A 4 A_Chase
    WZRD B 3 A_Chase
    WZRD B 4 A_Chase
    WZRD B 3 A_Chase
    WZRD B 4 A_Chase
    Loop
  Missile:
    WZRD C 4 A_WizAtk1
    WZRD C 4 A_WizAtk2
    WZRD C 4 A_WizAtk1
    WZRD C 4 A_WizAtk2
    WZRD C 4 A_WizAtk1
    WZRD C 4 A_WizAtk2
    WZRD C 4 A_WizAtk1
    WZRD C 4 A_WizAtk2
    WZRD D 12 A_WizAtk3
    Goto See
  Pain:
    WZRD E 3 A_GhostOff
    WZRD E 3 A_Pain
    Goto See
  Death:
    WZRD F 6 A_GhostOff
    WZRD G 6 A_Scream
    WZRD HI 6
    WZRD J 6 A_NoBlocking
    WZRD KL 6
    WZRD M -1 A_SetFloorClip
    Stop
  }
}